[FFmpeg-devel] [PATCH] lavc/vc1dsp: R-V V mspel_pixels
uk7b at foxmail.com
uk7b at foxmail.com
Sun May 12 15:43:15 EEST 2024
From: sunyuechi <sunyuechi at iscas.ac.cn>
C908 X60
vc1dsp.avg_vc1_mspel_pixels_tab[0][0]_c : 14.7 13.2
vc1dsp.avg_vc1_mspel_pixels_tab[0][0]_rvv_i32 : 2.5 2.2
vc1dsp.avg_vc1_mspel_pixels_tab[1][0]_c : 3.7 3.5
vc1dsp.avg_vc1_mspel_pixels_tab[1][0]_rvv_i64 : 1.0 1.2
vc1dsp.put_vc1_mspel_pixels_tab[0][0]_c : 9.0 8.0
vc1dsp.put_vc1_mspel_pixels_tab[0][0]_rvi : 1.0 1.0
vc1dsp.put_vc1_mspel_pixels_tab[1][0]_c : 2.5 2.2
vc1dsp.put_vc1_mspel_pixels_tab[1][0]_rvi : 0.5 0.5
---
libavcodec/riscv/Makefile | 1 +
libavcodec/riscv/vc1dsp_init.c | 16 +++++++++++-
libavcodec/riscv/vc1dsp_rvi.S | 47 +++++++++++++++++++++++++++++++++
libavcodec/riscv/vc1dsp_rvv.S | 48 ++++++++++++++++++++++++++++++++++
4 files changed, 111 insertions(+), 1 deletion(-)
create mode 100644 libavcodec/riscv/vc1dsp_rvi.S
diff --git a/libavcodec/riscv/Makefile b/libavcodec/riscv/Makefile
index f2348e259e..6f4869145a 100644
--- a/libavcodec/riscv/Makefile
+++ b/libavcodec/riscv/Makefile
@@ -58,6 +58,7 @@ RVV-OBJS-$(CONFIG_TAK_DECODER) += riscv/takdsp_rvv.o
OBJS-$(CONFIG_UTVIDEO_DECODER) += riscv/utvideodsp_init.o
RVV-OBJS-$(CONFIG_UTVIDEO_DECODER) += riscv/utvideodsp_rvv.o
OBJS-$(CONFIG_VC1DSP) += riscv/vc1dsp_init.o
+RV-OBJS-$(CONFIG_VC1DSP) += riscv/vc1dsp_rvi.o
RVV-OBJS-$(CONFIG_VC1DSP) += riscv/vc1dsp_rvv.o
OBJS-$(CONFIG_VP8DSP) += riscv/vp8dsp_init.o
RV-OBJS-$(CONFIG_VP8DSP) += riscv/vp8dsp_rvi.o
diff --git a/libavcodec/riscv/vc1dsp_init.c b/libavcodec/riscv/vc1dsp_init.c
index e47b644f80..2b7071d6ff 100644
--- a/libavcodec/riscv/vc1dsp_init.c
+++ b/libavcodec/riscv/vc1dsp_init.c
@@ -29,19 +29,33 @@ void ff_vc1_inv_trans_8x8_dc_rvv(uint8_t *dest, ptrdiff_t stride, int16_t *block
void ff_vc1_inv_trans_4x8_dc_rvv(uint8_t *dest, ptrdiff_t stride, int16_t *block);
void ff_vc1_inv_trans_8x4_dc_rvv(uint8_t *dest, ptrdiff_t stride, int16_t *block);
void ff_vc1_inv_trans_4x4_dc_rvv(uint8_t *dest, ptrdiff_t stride, int16_t *block);
+void ff_put_pixels16x16_rvi(uint8_t *dst, const uint8_t *src, ptrdiff_t line_size, int rnd);
+void ff_put_pixels8x8_rvi(uint8_t *dst, const uint8_t *src, ptrdiff_t line_size, int rnd);
+void ff_avg_pixels16x16_rvv(uint8_t *dst, const uint8_t *src, ptrdiff_t line_size, int rnd);
+void ff_avg_pixels8x8_rvv(uint8_t *dst, const uint8_t *src, ptrdiff_t line_size, int rnd);
av_cold void ff_vc1dsp_init_riscv(VC1DSPContext *dsp)
{
-#if HAVE_RVV
+#if HAVE_RV
int flags = av_get_cpu_flags();
+# if __riscv_xlen >= 64
+ if (flags & AV_CPU_FLAG_RVI & AV_CPU_FLAG_RV_MISALIGNED) {
+ dsp->put_vc1_mspel_pixels_tab[1][0] = ff_put_pixels8x8_rvi;
+ dsp->put_vc1_mspel_pixels_tab[0][0] = ff_put_pixels16x16_rvi;
+ }
+# endif
+#if HAVE_RVV
if (flags & AV_CPU_FLAG_RVV_I32 && ff_get_rv_vlenb() >= 16) {
dsp->vc1_inv_trans_4x8_dc = ff_vc1_inv_trans_4x8_dc_rvv;
dsp->vc1_inv_trans_4x4_dc = ff_vc1_inv_trans_4x4_dc_rvv;
+ dsp->avg_vc1_mspel_pixels_tab[0][0] = ff_avg_pixels16x16_rvv;
if (flags & AV_CPU_FLAG_RVV_I64) {
dsp->vc1_inv_trans_8x8_dc = ff_vc1_inv_trans_8x8_dc_rvv;
dsp->vc1_inv_trans_8x4_dc = ff_vc1_inv_trans_8x4_dc_rvv;
+ dsp->avg_vc1_mspel_pixels_tab[1][0] = ff_avg_pixels8x8_rvv;
}
}
#endif
+#endif
}
diff --git a/libavcodec/riscv/vc1dsp_rvi.S b/libavcodec/riscv/vc1dsp_rvi.S
new file mode 100644
index 0000000000..d4a1b5bf49
--- /dev/null
+++ b/libavcodec/riscv/vc1dsp_rvi.S
@@ -0,0 +1,47 @@
+/*
+ * Copyright (c) 2024 Institue of Software Chinese Academy of Sciences (ISCAS).
+ *
+ * This file is part of FFmpeg.
+ *
+ * FFmpeg is free software; you can redistribute it and/or
+ * modify it under the terms of the GNU Lesser General Public
+ * License as published by the Free Software Foundation; either
+ * version 2.1 of the License, or (at your option) any later version.
+ *
+ * FFmpeg is distributed in the hope that it will be useful,
+ * but WITHOUT ANY WARRANTY; without even the implied warranty of
+ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+ * Lesser General Public License for more details.
+ *
+ * You should have received a copy of the GNU Lesser General Public
+ * License along with FFmpeg; if not, write to the Free Software
+ * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
+ */
+
+#include "libavutil/riscv/asm.S"
+
+#if __riscv_xlen >= 64
+func ff_put_pixels8x8_rvi
+.rept 8
+ ld t0, (a1)
+ sd t0, (a0)
+ add a1, a1, a2
+ add a0, a0, a2
+.endr
+
+ ret
+endfunc
+
+func ff_put_pixels16x16_rvi
+.rept 16
+ ld t0, (a1)
+ ld t1, 8(a1)
+ sd t0, (a0)
+ sd t1, 8(a0)
+ add a1, a1, a2
+ add a0, a0, a2
+.endr
+
+ ret
+endfunc
+#endif
diff --git a/libavcodec/riscv/vc1dsp_rvv.S b/libavcodec/riscv/vc1dsp_rvv.S
index 4a00945ead..7c2b47f66c 100644
--- a/libavcodec/riscv/vc1dsp_rvv.S
+++ b/libavcodec/riscv/vc1dsp_rvv.S
@@ -111,3 +111,51 @@ func ff_vc1_inv_trans_4x4_dc_rvv, zve32x
vsse32.v v0, (a0), a1
ret
endfunc
+
+.macro mspel_op op pos n1 n2
+ add t1, \pos, a2
+ v\op\()e8.v v\n1, (\pos)
+ sh1add \pos, a2, \pos
+ v\op\()e8.v v\n2, (t1)
+.endm
+
+.macro mspel_op_all op pos a1 a2 a3 a4 a5 a6 a7 a8 a9 a10 a11 a12 a13 a14 a15 a16
+ mspel_op \op \pos \a1 \a2
+ mspel_op \op \pos \a3 \a4
+ mspel_op \op \pos \a5 \a6
+ mspel_op \op \pos \a7 \a8
+ mspel_op \op \pos \a9 \a10
+ mspel_op \op \pos \a11 \a12
+ mspel_op \op \pos \a13 \a14
+ mspel_op \op \pos \a15 \a16
+.endm
+
+func ff_avg_pixels16x16_rvv, zve32x
+ csrwi vxrm, 0
+ vsetivli zero, 16, e8, m1, ta, ma
+ mspel_op_all l a1 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31
+ mspel_op_all l a0 0 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15
+ vsetvli t0, zero, e8, m8, ta, ma
+ sub a0, a0, a2
+ vaaddu.vv v0, v0, v16
+ neg a2, a2
+ vaaddu.vv v8, v8, v24
+ vsetivli zero, 16, e8, m1, ta, ma
+ mspel_op_all s a0 15 14 13 12 11 10 9 8 7 6 5 4 3 2 1 0
+
+ ret
+endfunc
+
+func ff_avg_pixels8x8_rvv, zve64x
+ csrwi vxrm, 0
+ li t0, 64
+ vsetivli zero, 8, e8, mf2, ta, ma
+ vlse64.v v16, (a1), a2
+ vlse64.v v8, (a0), a2
+ vsetvli zero, t0, e8, m4, ta, ma
+ vaaddu.vv v16, v16, v8
+ vsetivli zero, 8, e8, mf2, ta, ma
+ vsse64.v v16, (a0), a2
+
+ ret
+endfunc
--
2.45.0
More information about the ffmpeg-devel
mailing list