[FFmpeg-devel] [PATCH 3/5] lavc/aarch64: Add neon implementation for pix_abs16_y2

Hubert Mazur hum at semihalf.com
Fri Jul 15 11:02:26 EEST 2022


Provide optimized implementation of pix_abs16_y2 function for arm64.

Performance comparison tests are shown below.
pix_abs_0_2_c: 308.5
pix_abs_0_2_neon: 39.2

Benchmarks and tests run with checkasm tool on AWS Graviton 3.

Signed-off-by: Hubert Mazur <hum at semihalf.com>
---
 libavcodec/aarch64/me_cmp_init_aarch64.c |  3 +
 libavcodec/aarch64/me_cmp_neon.S         | 74 ++++++++++++++++++++++++
 2 files changed, 77 insertions(+)

diff --git a/libavcodec/aarch64/me_cmp_init_aarch64.c b/libavcodec/aarch64/me_cmp_init_aarch64.c
index 72a2062e7e..07d62cc1e5 100644
--- a/libavcodec/aarch64/me_cmp_init_aarch64.c
+++ b/libavcodec/aarch64/me_cmp_init_aarch64.c
@@ -29,6 +29,8 @@ int ff_pix_abs16_xy2_neon(MpegEncContext *s, uint8_t *blk1, uint8_t *blk2,
                       ptrdiff_t stride, int h);
 int ff_pix_abs16_x2_neon(MpegEncContext *v, uint8_t *pix1, uint8_t *pix2,
                       ptrdiff_t stride, int h);
+int ff_pix_abs16_y2_neon(MpegEncContext *v, uint8_t *pix1, uint8_t *pix2,
+                      ptrdiff_t stride, int h);
 
 int sse16_neon(MpegEncContext *v, uint8_t *pix1, uint8_t *pix2,
                   ptrdiff_t stride, int h);
@@ -42,6 +44,7 @@ av_cold void ff_me_cmp_init_aarch64(MECmpContext *c, AVCodecContext *avctx)
     if (have_neon(cpu_flags)) {
         c->pix_abs[0][0] = ff_pix_abs16_neon;
         c->pix_abs[0][1] = ff_pix_abs16_x2_neon;
+        c->pix_abs[0][2] = ff_pix_abs16_y2_neon;
         c->pix_abs[0][3] = ff_pix_abs16_xy2_neon;
 
         c->sad[0] = ff_pix_abs16_neon;
diff --git a/libavcodec/aarch64/me_cmp_neon.S b/libavcodec/aarch64/me_cmp_neon.S
index bacf151314..858833b0ae 100644
--- a/libavcodec/aarch64/me_cmp_neon.S
+++ b/libavcodec/aarch64/me_cmp_neon.S
@@ -425,3 +425,77 @@ function sse4_neon, export=1
         ret
 
 endfunc
+
+function ff_pix_abs16_y2_neon, export=1
+        // x0           unused
+        // x1           uint8_t *pix1
+        // x2           uint8_t *pix2
+        // x3           ptrdiff_t stride
+        // x4           int h
+        // x5           uint8_t *pix2 + stride
+
+        // initialize buffers
+        movi            d18, #0
+        add             x5, x2, x3
+        cmp             w4, #4
+        b.lt            2f
+
+// make 4 iterations at once
+1:
+
+        // abs(pix1[0], avg2(pix2[0], pix2[0 + stride]))
+        // avg2(a, b) = (((a) + (b) + 1) >> 1)
+        // abs(x) = (x < 0 ? (-x) : (x))
+
+        ld1             {v1.16b}, [x2], x3
+        ld1             {v2.16b}, [x5], x3
+        urhadd          v30.16b, v1.16b, v2.16b
+        ld1             {v0.16b}, [x1], x3
+        uabdl           v29.8h, v0.8b, v30.8b
+        ld1             {v4.16b}, [x2], x3
+        uabdl2          v28.8h, v0.16b, v30.16b
+        ld1             {v5.16b}, [x5], x3
+        urhadd          v27.16b, v4.16b, v5.16b
+        ld1             {v3.16b}, [x1], x3
+        uabal           v29.8h, v3.8b, v27.8b
+        ld1             {v7.16b}, [x2], x3
+        uabal2          v28.8h, v3.16b, v27.16b
+        ld1             {v20.16b}, [x5], x3
+        urhadd          v26.16b, v7.16b, v20.16b
+        ld1             {v6.16b}, [x1], x3
+        uabal           v29.8h, v6.8b, v26.8b
+        ld1             {v22.16b}, [x2], x3
+        uabal2          v28.8h, v6.16b, v26.16b
+        ld1             {v23.16b}, [x5], x3
+        urhadd          v25.16b, v22.16b, v23.16b
+        ld1             {v21.16b}, [x1], x3
+        uabal           v29.8h, v21.8b, v25.8b
+        uabal2          v28.8h, v21.16b, v25.16b
+
+        add             v29.8h, v29.8h, v28.8h
+        sub             w4, w4, #4
+        uaddlv          s16, v29.8h
+        cmp             w4, #4
+        add             d18, d18, d16
+        b.ge            1b
+        cbz             w4, 3f
+
+// iterate by one
+2:
+
+        ld1             {v0.16b}, [x1], x3
+        ld1             {v1.16b}, [x2], x3
+        urhadd          v30.16b, v1.16b, v2.16b
+        ld1             {v2.16b}, [x5], x3
+        uabd            v30.16b, v30.16b, v30.16b
+
+        uaddlv          h17, v30.16b
+        subs            w4, w4, #1
+        add             d18, d18, d17
+        b.ne            2b
+
+3:
+        fmov            w0, s18
+
+        ret
+endfunc
-- 
2.34.1



More information about the ffmpeg-devel mailing list