[FFmpeg-devel] [PATCH 3/5] lavc/aarch64: Add neon implementation for vsad_intra16

[Hubert Mazur]

Provide optimized implementation for vsad_intra16 function for arm64.

Performance comparison tests are shown below.
- vsad_4_c: 177.2
- vsad_4_neon: 24.5

Benchmarks and tests are run with checkasm tool on AWS Gravtion 3.

Signed-off-by: Hubert Mazur <hum at semihalf.com>
---
 libavcodec/aarch64/me_cmp_init_aarch64.c |  3 ++
 libavcodec/aarch64/me_cmp_neon.S         | 58 ++++++++++++++++++++++++
 2 files changed, 61 insertions(+)

diff --git a/libavcodec/aarch64/me_cmp_init_aarch64.c b/libavcodec/aarch64/me_cmp_init_aarch64.c
index 7b81e48d16..af83f7ed1e 100644
--- a/libavcodec/aarch64/me_cmp_init_aarch64.c
+++ b/libavcodec/aarch64/me_cmp_init_aarch64.c
@@ -43,6 +43,8 @@ int sse4_neon(MpegEncContext *v, const uint8_t *pix1, const uint8_t *pix2,
 
 int vsad16_neon(MpegEncContext *c, const uint8_t *s1, const uint8_t *s2,
                 ptrdiff_t stride, int h);
+int vsad_intra16_neon(MpegEncContext *c, const uint8_t *s, const uint8_t *dummy,
+                      ptrdiff_t stride, int h) ;
 int vsse16_neon(MpegEncContext *c, const uint8_t *s1, const uint8_t *s2,
                 ptrdiff_t stride, int h);
 
@@ -64,6 +66,7 @@ av_cold void ff_me_cmp_init_aarch64(MECmpContext *c, AVCodecContext *avctx)
         c->sse[2] = sse4_neon;
 
         c->vsad[0] = vsad16_neon;
+        c->vsad[4] = vsad_intra16_neon;
 
         c->vsse[0] = vsse16_neon;
     }
diff --git a/libavcodec/aarch64/me_cmp_neon.S b/libavcodec/aarch64/me_cmp_neon.S
index 279bae7cb5..126e267fdc 100644
--- a/libavcodec/aarch64/me_cmp_neon.S
+++ b/libavcodec/aarch64/me_cmp_neon.S
@@ -756,3 +756,61 @@ function vsse16_neon, export=1
 
         ret
 endfunc
+
+function vsad_intra16_neon, export=1
+        // x0           unused
+        // x1           uint8_t *pix1
+        // x2           uint8_t *dummy
+        // x3           ptrdiff_t stride
+        // w4           int h
+
+        sub             w4, w4, #1 // we need to make h-1 iterations
+        add             x5, x1, x3 // pix1 + stride
+        cmp             w4, #4
+        movi            v16.8h, #0
+
+        b.lt            2f
+
+// make 4 iterations at once
+1:
+        // v = abs( pix1[0] - pix1[0 + stride] )
+        // score = sum(v)
+        // abs(x) = ( (x > 0) ? (x) : (-x) )
+
+        ld1             {v0.16b}, [x1], x3
+        ld1             {v1.16b}, [x5], x3
+        ld1             {v2.16b}, [x1], x3
+        uabal           v16.8h, v0.8b, v1.8b
+        ld1             {v3.16b}, [x5], x3
+        uabal2          v16.8h, v0.16b, v1.16b
+        ld1             {v4.16b}, [x1], x3
+        uabal           v16.8h, v2.8b, v3.8b
+        ld1             {v5.16b}, [x5], x3
+        uabal2          v16.8h, v2.16b, v3.16b
+        ld1             {v6.16b}, [x1], x3
+        uabal           v16.8h, v4.8b, v5.8b
+        ld1             {v7.16b}, [x5], x3
+        uabal2          v16.8h, v4.16b, v5.16b
+        sub             w4, w4, #4
+        uabal           v16.8h, v6.8b, v7.8b
+        cmp             w4, #4
+        uabal2          v16.8h, v6.16b, v7.16b
+
+        b.ge            1b
+        cbz            w4, 3f
+
+// iterate by one
+2:
+        ld1             {v0.16b}, [x1], x3
+        ld1             {v1.16b}, [x5], x3
+        subs            w4, w4, #1
+        uabal           v16.8h, v0.8b, v1.8b
+        uabal2          v16.8h, v0.16b, v1.16b
+        cbnz            w4, 2b
+
+3:
+        uaddlv          s17, v16.8h
+        fmov            w0, s17
+
+        ret
+endfunc
-- 
2.34.1